home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 01 (1982-09)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 01 (1982-09)(Softdisk)(Side B).do / UFO.II.bas < prev   
BASIC Source File  |  1996-12-24  |  15KB  |  326 lines
  1. 10  TEXT : HOME : CLEAR 
  2. 20  SPEED= 255
  3. 25 S =  -16336
  4. 30 A$ = "UFO II": GOSUB 7000
  5. 31 A$ = "WRITTEN BY LARRY SELTZER": GOSUB 7000
  6. 32  PRINT 
  7. 33 A$ = "BASED UPON A PROGRAM WRITTEN BY": GOSUB 7000
  8. 34 A$ = "RAYMOND J. KERNAY": GOSUB 7000
  9. 37 A$ = "FOR": GOSUB 7000
  10. 39 A$ = "CREATIVE COMPUTING": GOSUB 7000
  11. 40 A$ = "MORRISTOWN, NEW JERSEY": GOSUB 7000
  12. 50  VTAB 10
  13. 60  PRINT "DO YOU WANT INSTRUCTIONS "
  14. 62  VTAB 12: HTAB 1: PRINT "====>"
  15. 63  VTAB 12: HTAB 6: GET A$: PRINT A$
  16. 70  IF A$ = "N"  THEN 1000
  17. 80  IF A$ = "Y"  THEN 100
  18. 90  PRINT  CHR$(7)
  19. 95  GOTO 63
  20. 100  POKE 35,24
  21. 110  HOME 
  22. 160  PRINT "THE INFORMATION YOU ARE ABOUT TO": PRINT : PRINT "RECEIVE IS CLASSIFIED ";: FLASH : PRINT "TOP SECRET": NORMAL 
  23. 170  FOR X = 1 TO 500: NEXT X: PRINT : PRINT 
  24. 180  PRINT : PRINT "THIS IS THE YEAR 2080...": PRINT 
  25. 190  PRINT "CIVILIZATION AS YOU KNEW IT HAS BEEN": PRINT : PRINT "DESTROYED BY STRANGE CREATURES NEVER ": PRINT 
  26. 200  PRINT "BEFORE SEEN BY MAN."
  27. 210  PRINT : PRINT "THEY HAVE REDUCED NATIONS TO RUBBLE IN": PRINT : PRINT "A MASSIVE SPACE WAR."
  28. 220  GOSUB 8000
  29. 240  PRINT "YOU ARE NOW THE CAPTAIN OF THE SPACE": PRINT : PRINT "SHIP 'VOYAGER', WHOSE SOLE PURPOSE IS"
  30. 250  PRINT : PRINT "TO SAFE GUARD YOUR 150 PASSENGERS...THE"
  31. 260  PRINT : PRINT "SOLE SURVIVORS OF THE PLANET EARTH"
  32. 270  PRINT : PRINT : PRINT "MISSION:  FIND A PLANET SUITABLE FOR": PRINT : PRINT "YOUR COLONISTS"
  33. 280  PRINT : PRINT "PROBLEM:  THE ENEMY STILL EXISTS"
  34. 290  GOSUB 8000
  35. 300  PRINT "YOUR SHIP'S BATTERIES CONTAIN 10,000": PRINT : PRINT "UNITS OF ENERGY, WHICH IS THE MOST THEY": PRINT : PRINT "CAN SAFELY HOLD AT ANY ONE TIME."
  36. 310  PRINT : PRINT "WHEN YOU RUN OUT OF ENERGY, THE ALIENS": PRINT : PRINT "WILL DESTROY YOU."
  37. 320  GOSUB 8000
  38. 410  POKE 35,24: CALL  -936: HTAB 15: PRINT "WEAPONRY": PRINT 
  39. 420  PRINT "#";: HTAB 3: PRINT "DESCRIPTION";
  40. 430  HTAB 25: PRINT "RANGE"
  41. 440  PRINT "- ------------"; TAB( 25);"-----"
  42. 450  PRINT "1"; TAB( 3);"HEAVY GUNS"; TAB( 25);"0-25000"
  43. 460  PRINT "2"; TAB( 3);"PHOTON TORPEDOES"; TAB( 25);"1000-200000"
  44. 470  PRINT "3"; TAB( 3);"LASERS"; TAB( 25);"UNLIMITED"
  45. 480  PRINT : PRINT ; TAB( 16);"OPTIONS": PRINT 
  46. 490  PRINT "4"; TAB( 3);"APPROACH"
  47. 500  PRINT "5"; TAB( 3);"RETREAT"
  48. 510  PRINT "6 BY TYPING 6, YOU CAN LOSE YOUR TURN"
  49. 520  PRINT "   AND GAIN 500 UNITS OF POWER"
  50. 530  PRINT "    BUT YOU CANNOT INPUT COMMAND 6"
  51. 540  PRINT "     WHEN YOU HAVE FULL POWER"
  52. 550  PRINT "7"; TAB( 3);"RECALL OF COMMANDS"
  53. 560  PRINT "8"; TAB( 3);"REPORT OF EACH SHIP'S STATUS"
  54. 570  PRINT "9"; TAB( 3);"SELF-DESTRUCT"
  55. 580  IF C = 7  THEN 1210
  56. 590  GOSUB 8000
  57. 630  PRINT "THE FOLLOWING ARE DESCRIPTIONS OF YOUR": PRINT : PRINT "WEAPONS, WHICH ARE IDENTICAL IN EVERY": PRINT : PRINT "WAY TO THOSE OF THE ALIEN"
  58. 640  PRINT : PRINT "HEAVY GUNS":LG = 10: GOSUB 3800
  59. 650  PRINT "SUPPLY :AS LONG AS POWER LASTS"
  60. 660  PRINT "FUEL DRAIN :10 UNITS"
  61. 670  PRINT "DAMAGE TO ENEMY :100 UNITS"
  62. 680  PRINT : PRINT : PRINT "PHOTON TORPEDOES":LG = 16: GOSUB 3800
  63. 690  PRINT "SUPPLY :10 TORPEDOES"
  64. 700  PRINT "FUEL DRAIN :NONE"
  65. 710  PRINT "DAMAGE TO ENEMY :1500 UNITS"
  66. 720  GOSUB 8000
  67. 730  PRINT "LASERS":LG = 6: GOSUB 3800
  68. 740  PRINT "SUPPLY :AS LONG AS POWER LASTS"
  69. 750  PRINT "FUEL DRAIN :VARIABLE, PICKED BY YOU"
  70. 760  PRINT "DAMAGE TO ENEMY :FUEL DRAIN X % OF RANGE";
  71. 770  PRINT "(FROM 50% TO 150% OF FUEL DRAIN IS SPENT";: PRINT "ON ENEMY)"
  72. 780  PRINT : PRINT "THE CLOSER YOU ARE TO THE ENEMY, THE": PRINT : PRINT "MORE HE'LL BE DAMAGED BY YOUR LASERS"
  73. 790  GOSUB 8000
  74. 800  PRINT "SELF-DESTRUCT":LG = 13: GOSUB 3800
  75. 810  PRINT : PRINT "THE SELF-DESTRUCT MECHANISM SHOULD ONLY": PRINT : PRINT "BE USED IN AN EMERGENCY"
  76. 820  PRINT : PRINT "WHEN THE SHIP BLOWS UP, THE ENEMY": PRINT : PRINT "SUFFERS LOSSES EQUAL TO YOUR TOTAL"
  77. 830  PRINT : PRINT "POWER PLUS 500 X EACH PHOTON TORPEDO": PRINT : PRINT "THIS RESULT IS THEN MULTIPLIED BY A "
  78. 840  PRINT : PRINT "NUMBER BETWEEN .4 AND 1, DEPENDING ON": PRINT : PRINT "YOUR RANGE"
  79. 850  GOSUB 8000
  80. 860  PRINT "BOTH SHIPS ARE ON THE SAME MISSION, SO": PRINT : PRINT "UNFORTUNATELY, YOU EACH MUST KILL THE": PRINT : PRINT "OTHER TO WIN."
  81. 870  PRINT : PRINT : PRINT "THIS IS A RECORDED MESSAGE.": PRINT : PRINT "BY THE TIME YOU FINISH READING THIS,"
  82. 880  PRINT : PRINT "EARTH WILL BE DEAD"
  83. 890  PRINT : FLASH : PRINT "GOOD LUCK": NORMAL 
  84. 900  GOSUB 8000
  85. 1000 PT = 10:PT(1) = 10
  86. 1010  SPEED= 255
  87. 1020  PRINT "THIS IS COMPUTER CONTROL..."
  88. 1022  PRINT : PRINT "WHAT IS YOUR NAME?"
  89. 1023  PRINT : INPUT "===>";N$
  90. 1030  CALL  -936:P = 10000:P(1) = 10000:A =  INT( RND(1) *200000) +1
  91. 1040  PRINT "ENTER SELF-DESTRUCT PASSWORD, ";N$
  92. 1045  PRINT : INPUT "===>";SF$
  93. 1050  HOME 
  94. 1060 B = 900000
  95. 1070  PRINT "LEAVING PLANETARY ORBIT ON AUTO PILOT"
  96. 1080  PRINT : PRINT "ENEMY SHIP CLOSING FAST": PRINT : PRINT "RANGE :";B;: HTAB 20: FLASH : PRINT "OUT OF RANGE": NORMAL 
  97. 1090  VTAB 5: HTAB 8: PRINT "       "
  98. 1100  FOR B = 900000 TO A  STEP  -1234
  99. 1110  VTAB 5: HTAB 8: PRINT B;" ": NEXT B
  100. 1120  VTAB 5: HTAB 20: FLASH : PRINT "IN RANGE";: NORMAL : PRINT "        "
  101. 1130  VTAB 5: HTAB 8: PRINT A
  102. 1140  PRINT : PRINT : PRINT "AUTO PILOT OFF"
  103. 1200  POKE 35,18
  104. 1210  PRINT : PRINT "WHAT ";: GOSUB 4100: PRINT "ARE ";: GOSUB 4100: PRINT "YOUR ";: GOSUB 4100
  105. 1220  PRINT "ORDERS, ";: GOSUB 4100: PRINT "CAPTAIN ";: GOSUB 4100: PRINT N$;"?": GOSUB 4100
  106. 1230  GET A$
  107. 1240 C =  VAL(A$)
  108. 1250  IF C = 0  THEN C = 7
  109. 1260 O =  INT( RND(8) *2) +1
  110. 1270  IF C <1  OR C >9  THEN 1230
  111. 1280  CALL  -936
  112. 1290 CV = 1
  113. 1500  ON C GOTO 1510,1610,1710,1820,1850,1890,410,1940,4500
  114. 1510  PRINT : IF A < = 25000  THEN 1540
  115. 1520  PRINT : PRINT "RANGE HAS TO BE 25000 MILES OR LESS": PRINT : PRINT "CURRENT RANGE IS ";A;" MILES"
  116. 1530  GOTO 1200
  117. 1540 P = P -10: PRINT "GUNS FIRED ";: GOSUB 3500
  118. 1550  IF O = 1  THEN 1570
  119. 1560  PRINT "MISSED": GOTO 1920
  120. 1570  PRINT "DIRECT HIT!": GOSUB 3900
  121. 1580 LL = A * -1/10000 +7/2
  122. 1590  PRINT "ENEMY LOSSES "; INT(LL *100);" UNITS"
  123. 1600 P(1) = P(1) -LL *100: GOTO 1920
  124. 1610  PRINT : IF PT >0  THEN 1630
  125. 1620  PRINT "CAPTAIN, WE HAVE NO MORE TORPEDOES": GOTO 1200
  126. 1630  IF A >1000  THEN 1650
  127. 1640  PRINT "WE ARE TOO CLOSE TO USE OUR TORPEDOES": PRINT : PRINT "WITHOUT DAMAGE TO OUR SHIP": GOTO 1200
  128. 1650 PT = PT -1: PRINT "TORPEDOES LAUNCHED";: GOSUB 3600
  129. 1660  IF O = 1  THEN 1680
  130. 1670  PRINT "MISSED": GOTO 1920
  131. 1680  PRINT "DIRECT HIT": GOSUB 3900
  132. 1690  PRINT "ENEMY LOSSES 1500 UNITS"
  133. 1700 P(1) = P(1) -1500: GOTO 1920
  134. 1710  INPUT "ENERGY TO FIRE?";E
  135. 1720  IF E < = 0  THEN 1210
  136. 1730  IF P -E < = 0  THEN 1750
  137. 1740 P = P -E: GOTO 1760
  138. 1750  PRINT "CAPTAIN, WE ONLY HAVE ";P: GOTO 1200
  139. 1760  PRINT "LAZERS FIRED";: GOSUB 3700
  140. 1770  IF O = 1  THEN 1790
  141. 1780  PRINT "MISSED": GOTO 1920
  142. 1790  PRINT "DIRECT HIT":LL = A * -1/200000 +1.5: GOSUB 3900
  143. 1800  PRINT "ENEMY LOSSES ";LL *E;" UNITS"
  144. 1810 P(1) = P(1) -LL *E: GOTO 1920
  145. 1820 B =  RND(1) *20000 +10000:A = A -B:P = P -B/1000
  146. 1830  IF A <1  THEN 3000: GOTO 1920
  147. 1840  GOTO 1920
  148. 1850 B =  RND(1) *20000 +10000:A = A +B:P = P -B/1000
  149. 1860  IF A >200000  THEN 1880
  150. 1870  GOTO 1920
  151. 1880  PRINT "CAPTAIN, AT THIS RANGE WE CANNOT REACH THE ENEMY WITH ANY OF OUR GUNS": GOTO 1920
  152. 1890  IF P > = 10000  THEN 1910
  153. 1900 P = P +500: GOTO 1920
  154. 1910  PRINT "CAPTAIN, OUR FUEL TANKS CANNOT HOLD ANY MORE ENERGY":P = 10000: GOTO 1920
  155. 1920  PRINT : IF P(1) < = 0  THEN P(1) = 0
  156. 1930  IF C(1) = 1  THEN  GOSUB 5500
  157. 1940 F(1) = 0:CV = 7: GOSUB 6000
  158. 1950  PRINT : IF C = 8  THEN 2180
  159. 1960  IF P(1) <1  THEN 2390
  160. 1970  IF P(1) <500  THEN 2250
  161. 1980 Z =  INT( RND(1) *2) +1:F(1) = 0: IF Z < >2  THEN 2220
  162. 1990 O =  INT( RND(1) *2) +1
  163. 2000 X =  INT( RND(1) *3) +1
  164. 2010  ON X GOTO 2020,2080,2130
  165. 2020 E1 =  INT(P(1) *.1 + INT(A/5000)):P(1) = P(1) -E1
  166. 2030  PRINT "ENEMY FIRES LAZERS";: GOSUB 3700
  167. 2040  IF O = 1  THEN 2060
  168. 2050  PRINT "MISSED!": GOTO 2180
  169. 2060  PRINT "DIRECT HIT":LL = A * -1/200000 +1.5:P = P -LL *E1: GOSUB 3900
  170. 2070  PRINT LL *E1;" UNIT LOSS FROM ENEMY": GOTO 2180
  171. 2080  IF PT(1) = 0  THEN 2000
  172. 2090 PT(1) = PT(1) -1: PRINT "ENEMY FIRES": PRINT "PHOTON TORPEDOES";: GOSUB 3600
  173. 2100  IF O = 1  THEN 2120
  174. 2110  PRINT "MISSED!": GOTO 2180
  175. 2120 P = P -1500: PRINT "DIRECT HIT": GOSUB 3900: GOTO 2180
  176. 2130  IF A >25000  THEN 2000
  177. 2140 P(1) = P(1) -10: PRINT "ENEMY FIRES": PRINT "HEAVY GUNS";: GOSUB 3500
  178. 2150  IF O = 1  THEN 2170
  179. 2160  PRINT "MISSED!": GOTO 2180
  180. 2170  PRINT "DIRECT HIT": GOSUB 3900
  181. 2180  IF P < = 0  THEN P = 0
  182. 2190 CV = 15: PRINT : PRINT :F(1) = F(1) +1: GOSUB 6000
  183. 2200  IF P <1  THEN 2440
  184. 2210  IF F(1) = 1  THEN 1200
  185. 2220 X =  INT( RND(3) *3) +1
  186. 2230  ON X GOTO 2240,2260,2310
  187. 2240  IF P(1) >10000  THEN 2220
  188. 2250 P(1) = P(1) +500: PRINT "ENEMY SHIP RESTING AND GAINING 500 UNITS OF ENERGY": GOTO 2190
  189. 2260  IF A <24000  THEN 2220
  190. 2270 B =  RND(1) *20000 +10000:A = A -B:P(1) = P(1) -B/1000
  191. 2280  PRINT "ENEMY SHIP APPROACHING": PRINT : PRINT "CURRENT RANGE  :";A
  192. 2290  FOR X = 1 TO 75: NEXT X: IF A < = 0  THEN 3000
  193. 2300  GOTO 2190
  194. 2310 B =  RND(1) *20000 +10000:A = A +B:P(1) = P(1) -B/1000: IF A >200000  THEN A = 200000
  195. 2320  PRINT "ENEMY SHIP RETREATING": PRINT : PRINT "CURRENT RANGE  :";A: GOTO 2190
  196. 2330  IF P < = 0  OR A <0  THEN 2350
  197. 2340  GOTO 2190
  198. 2350  IF A < = 0  THEN 3000
  199. 2360  PRINT : PRINT : PRINT "ENEMY IS VICTOR"
  200. 2370 S$ = "LIFE SUPPORT FADING..."
  201. 2380  FOR X = 1 TO 22: PRINT  MID$ (S$,X,1);: FOR Y = 1 TO X *50: NEXT Y: NEXT X: GOTO 2450
  202. 2390  SPEED= 175: PRINT : PRINT "ENEMY'S SHIP IS WITHOUT POWER.": PRINT "SENSERS DO NOT PICK UP ANY LIFE FORMS."
  203. 2400  FLASH 
  204. 2410  PRINT "MISSION SUCCESSFUL!!!!"
  205. 2420  NORMAL 
  206. 2430  PRINT "CONGRATULATIONS ";N$: GOTO 2450
  207. 2440  GOTO 2360
  208. 2450  PRINT : INPUT "AGAIN (Y/N) ===>";N$
  209. 2470  IF N$ = "N"  THEN  END 
  210. 2480  IF N$ = "Y"  THEN 10
  211. 2490  GOTO 2460
  212. 2930  GOTO 3190
  213. 2980  GOTO 2410
  214. 3000  CALL  -936:S =  -16336
  215. 3010  FLASH 
  216. 3020  GOSUB 3060
  217. 3030  VTAB 1: HTAB 1: INVERSE : SPEED= 210: GOSUB 3070
  218. 3040  HTAB 1: VTAB 1: NORMAL : GOSUB 3070
  219. 3050  GOTO 3170
  220. 3060  POKE 35,24: CALL  -936
  221. 3070  POKE 35,24
  222. 3080  PRINT "*****   *******  *******  **   **"
  223. 3090  PRINT "**  **  **   **  **   **  *** ***"
  224. 3100  PRINT "**  **  **   **  **   **  ** * **"
  225. 3110  PRINT "*****   **   **  **   **  **   **"
  226. 3120  PRINT "**  **  **   **  **   **  **   **"
  227. 3130  PRINT "**  **  **   **  **   **  **   **"
  228. 3140  PRINT "*****   *******  *******  **   **"
  229. 3150  GOSUB 4000
  230. 3160  RETURN 
  231. 3170  SPEED= 255: PRINT : PRINT : PRINT "***  COLLISION ***"
  232. 3180  PRINT : PRINT "BOTH SHIPS DESTROYED"
  233. 3190  PRINT : PRINT "THAT WAS A DUMB THING TO DO ";N$;"!!!": PRINT 
  234. 3200  PRINT "YOUR MISSION WAS TO PROTECT YOUR": PRINT : PRINT "PASSENGERS, NOT GET THEM KILLED"
  235. 3210  GOTO 2450
  236. 3220  END 
  237. 3500  FOR X = 1 TO 10: FOR Y = 1 TO 16: NEXT Y: PRINT ".";:SO =  PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S): NEXT X: RETURN 
  238. 3600  FOR X = 1 TO 10: FOR Y = 1 TO 90: NEXT Y: PRINT "#";
  239. 3610  FOR YY = 1 TO 5:S0 =  PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S) - PEEK(S): NEXT YY: NEXT X: RETURN 
  240. 3700  FOR X = 1 TO 10: FOR Y = 1 TO 30: NEXT Y: PRINT "-";
  241. 3710  FOR YY = 1 TO 8:SO =  PEEK(S) - PEEK(S): NEXT YY: NEXT X: RETURN 
  242. 3800  FOR X = 1 TO LG: PRINT "-";: NEXT X: PRINT : RETURN 
  243. 3900  FOR X = 1 TO 10: FOR XX = 1 TO 10:SO =  PEEK(S): NEXT XX: FOR Y = 1 TO 20: NEXT Y:SI =  PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S): NEXT X: RETURN 
  244. 4000  FOR X = 1 TO 15: FOR XX = 1 TO 10:SO =  PEEK(S): NEXT XX: FOR YY = 1 TO 20: NEXT YY:SO =  PEEK(S) - PEEK(S): NEXT X: RETURN 
  245. 4100  FOR XX = 1 TO 10:SO =  PEEK(S): NEXT XX: FOR YY = 1 TO 50: NEXT YY:SO =  PEEK(S) - PEEK(S): RETURN 
  246. 4200  FOR X = 1 TO 40:SO =  PEEK(S) - PEEK(S): NEXT X: FOR X = 1 TO 30: NEXT X
  247. 4210  FOR Y = 1 TO 30: NEXT Y
  248. 4220  FOR X = 1 TO 35:SO =  PEEK(S): NEXT X
  249. 4230  FOR Y = 1 TO 20: NEXT Y: RETURN 
  250. 4500  INPUT "ENTER SELF-DESTRUCT PASSWORD";SD$
  251. 4510  IF SD$ = SF$  THEN 4530
  252. 4520  GOTO 1200
  253. 4530  TEXT : HOME : FLASH 
  254. 4540  FOR YX = 1 TO 30: HTAB 13: VTAB 2: PRINT "EVACUATE SHIP"
  255. 4550  IF YX = 4  THEN 4590
  256. 4560  IF YX > = 21  THEN 4640
  257. 4570  IF YX > = 15  THEN 4610
  258. 4580  GOTO 4650
  259. 4590  VTAB 3: PRINT : PRINT "ALL PASSENGERS TO EMERGENCY PODS"
  260. 4600  GOTO 4650
  261. 4610  VTAB 3: PRINT : NORMAL : PRINT "                                       ": VTAB 3: FLASH : PRINT 
  262. 4620  PRINT "PODS WILL LAUNCH IN T-MINUS ";20 -YX
  263. 4630  GOTO 4650
  264. 4640  VTAB 3: PRINT : NORMAL : PRINT "                                      ": VTAB 3: FLASH : PRINT : HTAB 13: PRINT "PODS LAUNCHED"
  265. 4650  GOSUB 4200: NEXT YX
  266. 4660  HTAB 13: VTAB 2: PRINT "SHIP EVACUATED": NORMAL 
  267. 4670  PRINT : PRINT "ALL PASSENGERS ARE LOADED IN EMERGENCY"
  268. 4680  PRINT : PRINT "PODS AND ARE A SAFE DISTANCE FROM SHIP"
  269. 4690  PRINT : PRINT "PRESS KEY '9' AND THE SHIP WILL DETONATE"
  270. 4700 CC =  PEEK( -16384)
  271. 4710  IF CC = 185  THEN 4740
  272. 4720  GOSUB 4200
  273. 4730  GOTO 4700
  274. 4740  POKE  -16368,0: CALL  -936: GOSUB 3060
  275. 4750 LL = A * -.6/200000 +1
  276. 4760 EL = LL *(P +PT *500)
  277. 4770 P(1) = P(1) -EL: IF P(1) < = 0  THEN 4900
  278. 4780  PRINT : PRINT : PRINT "ENEMY STILL HAS POWER": FOR X = 1 TO 200
  279. 4790  PRINT : PRINT "FIRES LASERS";
  280. 4800  GOSUB 3700
  281. 4810  PRINT "DIRECT HIT": GOSUB 3900
  282. 4820  PRINT : PRINT "ALL PODS DESTROYED"
  283. 4830  GOTO 3190
  284. 4900 DI =  INT( RND(8) *20000) +1
  285. 4910  IF P < = DI  THEN 4950
  286. 4920  PRINT N$;" YOU DESTROYED THE ENEMY, BUT YOU "
  287. 4925  PRINT : PRINT "DON'T HAVE ENOUGH FUEL TO MAKE IT TO"
  288. 4928  PRINT : PRINT "A PLANET..."
  289. 4930  GOTO 3190
  290. 4950  PRINT : PRINT "NOT ONLY DID YOU DESTROY THE ENEMY, "
  291. 4960  PRINT : PRINT "BUT YOU SAFELY GUIDED YOUR PASSENGERS"
  292. 4970  PRINT : PRINT "TO A PLANET."
  293. 4980  GOTO 2430
  294. 5500  IF A <RR  THEN 5550
  295. 5510 A = A -15000:P = P -15: IF A >RR  THEN 5530
  296. 5520 A = RR:C(1) = 0
  297. 5530  PRINT "SHIP ADVANCING TO ";A
  298. 5540  RETURN 
  299. 5550 A = A +15000:P = P -15: IF A <RR  THEN 5570
  300. 5560 A = RR:C(1) = 0
  301. 5570  PRINT "SHIP RETREATING TO ";A: RETURN 
  302. 6000  POKE 35,24: VTAB 19: CALL  -868
  303. 6010  VTAB 19: HTAB 13: PRINT "RANGE: ";A
  304. 6020  VTAB 20: PRINT "ENEMY SHIP REPORT"; TAB( 20);"VOYAGER REPORT"
  305. 6030  VTAB 21:LG = 17: GOSUB 3800: VTAB 21: HTAB 20:LG = 14: GOSUB 3800
  306. 6040 P =  INT(P):P(1) =  INT(P(1))
  307. 6050  IF P >10000  THEN P = 10000
  308. 6060  IF P(1) >10000  THEN P(1) = 10000
  309. 6070  VTAB 22: CALL  -868
  310. 6080  VTAB 22: PRINT "POWER"; TAB( 12);":";P(1); TAB( 20);"POWER"; TAB( 32);":";P
  311. 6090  VTAB 23: CALL  -868
  312. 6100  VTAB 23: PRINT "TORPEDOES"; TAB( 12);":";PT(1); TAB( 20);"TORPEDOES"; TAB( 32);":";PT
  313. 6110  VTAB CV +1
  314. 6120  POKE 35,18
  315. 6130  RETURN 
  316. 7000  PRINT  TAB( (40 - LEN(A$))/2);A$
  317. 7010  RETURN 
  318. 8000  VTAB 24
  319. 8010  PRINT "TO CONTINUE, PLEASE PRESS THE ";
  320. 8020  FLASH 
  321. 8030  PRINT "SPACE BAR";
  322. 8040  NORMAL 
  323. 8050  IF  PEEK( -16384) < >160  THEN 8050
  324. 8060  POKE  -16368,0
  325. 8070  HOME 
  326. 8080  RETURN